video 2 - Getting Started with Trove Modding - Video Notes page

Created by Etaew

Extracting Game Files

You need to extract game files to be able to modify them. You can download specific blueprints directly from the Trovesaurus website, but having your whole game client extracted and accessible is very useful.

Ways you can extract the game:

Use TroveTools.NET

From: https://dazotrove.github.io/TroveTools.NET/

Use EnhancedTroveArchiveExtractor

From: https://github.com/Sly0511/EnhancedTroveArchiveExtractor

Use a .bat file

For that, you need a devtool_unpack_client.bat file, same as convert_to_blueprint and other devtools.

Download link : https://trovesaurus.com/files/devtool_unpack_client.bat

You can make same .bat yourself with the following code (provided by Ignitas on GitHub)

▼Code of devtool_unpack_client.bat file

@echo off
if not exist "%~dp0\Trove.exe" (
  echo. Error: Couldn't find Trove.exe
  echo. Please but this .bat script inside your Trove folder and retry!
  echo.&pause&goto:eof
)

echo. This script will extract all client files to the extracted folder.
echo. All current contents of the extracted folder will be overwritten.
echo. Please make backups of your modifications before continuing!
set /p test=Do you want to continue? (y/n)
if not "%test%" == "y" exit

rmdir /Q /S extracted
call:extractFolder "%~dp0"

echo.
echo. Completed extraction of the clientfiles to:
echo. "%~dp0"\extracted
echo.&pause&goto:eof

:extractFolder
for /D %%f in ("%~1*") do (
  if not "%%~nf" == "extracted" (
    if exist "%~2%%~nf\index.tfi" (
      echo. extracting %~2%%~nf
      "%~dp0Trove.exe" -tool extractarchive %~2%%~nf extracted\%~2%%~nf
    )
    call:extractFolder "%~1%%~nf\", "%~2%%~nf\"
  )
)
goto:eof

To turn the code into the working .bat file you need to create a New text document, copy the code and paste it into the .txt file. Next, select Save As.. and instead of a New Text Document.txt type New Text Document.bat as the name. Clicking on Save will turn that .txt into an executable .bat . Change the name to devtool_unpack_client in case you have not already done that.

Place the .bat file into your Trove/Live folder and run it (double click on it). If placed in wrong folder the .bat will show an error message. If placed in correct folder it will ask for a conformation - press y and hit Enter if you'd like to extract the client.

Extracting files will take few minutes, .bat will show a 'Completed Extraction to..(folder path)' message when its done. Press any key to continue - close the .bat window.

Important Note: with each update in-game files get changed and/or new files get added. If you can not find something in your /extracted folder it is possible that files you are looking for have been released after your last unpacking and you need to run that again.

 

 

Comments and Likes Comments 0
Like 0

You must be logged in to add a comment.

No comments or likes yet!